Anarchy Mods, Forums Feed

How to log in a super and public admins?

1/21/2009 7:51:28 PM

Ive set the appropate passwords in the anarchy server prefs file.

But I cannot not find the commands or how to login as super or pub admins.

I used to do this on base servers, but have long for gotin the console commands.

Anarchy Mod for Linux

11/29/2008 8:54:38 PM

It is possibly the wrong version as the .dso files are not platform dependent.

I will update the downloads page with the linux install. Basically it is just unzipping the mod files to the mod folder and adding the options to the exe for the game.

I will make sure the links for everything are correct. Since the site move I have been fixing broken links as they are found.,

I noticed there are zip files for a Tribes 2 Anarchy Mod for Linux. But the links don't work. Nor do the links work for the Linux update patch.

I've come across a download link for Tribes 2 - Linux here:

http://t2.giantfriend.com/

As of 10/4/2008 the link still works. The archive has just about every custom script installed along with it. But I can't get the Anarchy Mod to work -- if I just copy from a Win32 install to a Linux install. I assume the .dso files aren't compatible for some reason. That or my version is wrong.

Deployable Jumppad Difficulty Moderate

7/25/2008 1:52:07 PM

---------------------------------------------------------------------------------------------------------------
Jumpad Tutorial
---------------------------------------------------------------------------------------------------------------
This creates a deployable Jumpad that launches people into the air when touched. It's created as an item, instead of static, due to the greater sensitivity of item collisions when flat.
Step #1
// ------------------------------------------
// defaultGame.cs
// ------------------------------------------

function DefaultGame::clearDeployableMaxes(%game)
{

$TeamDeployedCount[%i, JumpadDeployable] = 0;

}

Step #2
// ------------------------------------------
// deployables.cs
// ------------------------------------------

2a)Near the top of the file add this:

$TeamDeployableMax[JumpadDeployable] = 5;

2b)All of this takes place in function ShapeBaseImageData::onDeploy:

   if(%item.deployed.className $= "DeployedTurret")
      %className = "Turret";
   else
      %className = "StaticShape";

becomes:

   if(%item.deployed.className $= "DeployedTurret")
      %className = "Turret";
   else if (%item.deployed.className $= "Jumpad")
      %className = "Item";
   else
      %className = "StaticShape";

   %deplObj = new (%className)()
   {
      dataBlock = %item.deployed;
   };

becomes:

   if (%item.deployed.classname $= "Jumpad")
   {
      %deplObj = new (%className)()
      {
         dataBlock = %item.deployed;
         scale = "0.55 0.7 0.3";
      };
   }
   else
   {
      %deplObj = new (%className)()
      {
         dataBlock = %item.deployed;
      };
   }

   if(%className $= "Turret")
      %deplObj.setDeployRotation(%item.surfacePt, %item.surfaceNrm);
   else
      %deplObj.setTransform(%item.surfacePt SPC %rot);

becomes:

   if(%className $= "Turret")
      %deplObj.setDeployRotation(%item.surfacePt, %item.surfaceNrm);
   else if (%item.deployed.classname $= "Jumpad")
      %deplObj.setDeployRotation(getWords(%item.surfacePt, 0, 1) SPC getWord(%item.surfacePt, 2) + 0.1, %item.surfaceNrm);
   else
      %deplObj.setTransform(%item.surfacePt SPC %rot);

%deplObj.deploy();

becomes:

if (%classname !$= "Item")
%deplObj.deploy();

Step #3
// ------------------------------------------
// inventoryHud.cs
// ------------------------------------------
Add this near the top of the file:

$InvPack[18] = "Jump Pad";
$NTInvPack[11] = "Jump Pad";
$NameToInv["Jump Pad"] = "JumpadDeployable";

Step #4
// ------------------------------------------
// pack.cs
// ------------------------------------------
exec("scripts/packs/Jumpad.cs");

Step #5
// ------------------------------------------
// repairpack.cs
// ------------------------------------------
Find both instances of '%searchMasks =' in the file and add '| $TypeMasks::ItemObjectType' so the jumpad can be repaired.

Step #6
// ------------------------------------------
// player.cs
// ------------------------------------------

6a) In each player datablock add this. Since it's a deployable, only mediums and heavies need it.
max[JumpadDeployable] = 1;

6b) At the bottom of function Armor::onCollision add this: (This handles the impulse. Adjust the 2200 for horizontal push and 7500 for vertical push).

      else if (%className $= "Jumpad")
      {
         if (%col.team == %obj.team)
         {
            %position = getWords(%obj.getTransform(), 0, 2);
            %vel = %obj.getVelocity();
            %x1 = getWord(%vel, 0) * 2200;
            %y1 = getWord(%vel, 1) * 2200;
            %impulseVec = %x1 SPC %y1 SPC 7500;
            %obj.applyImpulse(%position, %impulseVec);
            %obj.playAudio(0, MortarFireSound);
         }
      }

Step #7
// ------------------------------------------
// Jumpad.cs
// ------------------------------------------
Create a new file called Jumpad.cs in your packs directory and add all this:

//--------------------------------------------------------------------------
// Jumpad
//
//
//--------------------------------------------------------------------------

datablock ItemData(DeployedJumpad) : StaticShapeDamageProfile
{
   className = Jumpad;
   shapeFile = "dmiscf.dts"; // dmiscf.dts, alternate
   maxDamage = 2.0;
   destroyedLevel = 2.0;
   disabledLevel = 2.0;
   pickupRadius = 1;
   sticky=true;

   explosion      = HandGrenadeExplosion;
      expDmgRadius = 3.0;
      expDamage = 0.1;
      expImpulse = 200.0;
   dynamicType = $TypeMasks::StaticShapeObjectType;
   deployedObject = true;
   cmdCategory = "DSupport";
   cmdIcon = CMDSensorIcon;
   cmdMiniIconName = "commander/MiniIcons/com_deploymotionsensor";
   targetNameTag = 'Jump';
   targetTypeTag = 'Pad';
   deployAmbientThread = true;
   debrisShapeName = "debris_generic_small.dts";
   debris = DeployableDebris;
   heatSignature = 0;
};

datablock ShapeBaseImageData(JumpadDeployableImage)
{
   mass = 10;
   emap = true;
   shapeFile = "Stackable1s.dts";
   item = JumpadDeployable;
   mountPoint = 1;
   offset = "0 0 0";
   deployed = DeployedJumpad;
   heatSignature = 0;

stateName[0] = "Idle";
stateTransitionOnTriggerDown[0] = "Activate";

   stateName[1] = "Activate";
   stateScript[1] = "onActivate";
   stateTransitionOnTriggerUp[1] = "Idle";

   isLarge = true;
   maxDepSlope = 30; // 30
   deploySound = ItemPickupSound;

minDeployDis = 0.5;
maxDeployDis = 5.0;
};

datablock ItemData(JumpadDeployable)
{
   className = Pack;
   catagory = "Deployables";
   shapeFile = "Stackable1s.dts";
   mass = 5.0;
   elasticity = 0.2;
   friction = 0.6;
   pickupRadius = 1;
   rotate = true;
   image = "JumpadDeployableImage";
   pickUpName = "a jump pad";
   heatSignature = 0;
   emap = true;
};

function JumpadDeployable::onPickup(%this, %obj, %shape, %amount)
{
// created to prevent console errors
}

function DeployedJumpad::onDestroyed(%this, %obj, %prevState)
{
   Parent::onDestroyed(%this, %obj, %prevState);
   $TeamDeployedCount[%obj.team, JumpadDeployable]--;
   %obj.schedule(500, "delete");
}

//Functions below here give StaticShape damage to the Jumpad item.
function DeployedJumpad::onDamage(%this,%obj)
{
   // Set damage state based on current damage level
   %damage = %obj.getDamageLevel();
   if(%damage >= %this.destroyedLevel)
   {
      if(%obj.getDamageState() !$= "Destroyed")
      {
         %obj.setDamageState(Destroyed);
         // if object has an explosion damage radius associated with it, apply explosion damage
         if(%this.expDmgRadius)
            RadiusExplosion(%obj, %obj.getWorldBoxCenter(), %this.expDmgRadius, %this.expDamage, %this.expImpulse, %obj, $DamageType::Explosion);
      }
   }
   else
   {
      if(%damage >= %this.disabledLevel)
      {
         if(%obj.getDamageState() !$= "Disabled")
            %obj.setDamageState(Disabled);
      }
      else
      {
         if(%obj.getDamageState() !$= "Enabled")
            %obj.setDamageState(Enabled);
      }
   }
}

function DeployedJumpad::damageObject(%data, %targetObject, %sourceObject, %position, %amount, %damageType)
{
   // if this is a non-team mission type and the object is "protected", don't damage it
   if(%data.noIndividualDamage && Game.allowsProtectedStatics())
      return;

   // if this is a Siege mission and this object shouldn't take damage (e.g. vehicle stations)
   if(%data.noDamageInSiege && Game.class $= "SiegeGame")
      return;

   if(%sourceObject)
   {
      if(%sourceObject.client)
      {
        %targetObject.lastDamagedBy = %sourceObject.client;
        %targetObject.lastDamagedByTeam = %sourceObject.client.team;
        %targetObject.damageTimeMS = GetSimTime();
      }
      else
      {
        %targetObject.lastDamagedBy = %sourceObject;
        %targetObject.lastDamagedByTeam = %sourceObject.team;
        %targetObject.damageTimeMS = GetSimTime();
      }
   }

   // Scale damage type & include shield calculations...
   if (%data.isShielded)
      %amount = %data.checkShields(%targetObject, %position, %amount, %damageType);

   %damageScale = %data.damageScale[%damageType];
   if(%damageScale !$= "")
      %amount *= %damageScale;

    //if team damage is off, cap the amount of damage so as not to disable the object...
    if (!$TeamDamage && !%targetObject.getDataBlock().deployedObject)
    {
       //see if the object is being shot by a friendly
       if(%sourceObject.getDataBlock().catagory $= "Vehicles")
          %attackerTeam = getVehicleAttackerTeam(%sourceObject);
       else %attackerTeam = %sourceObject.team;

      if (isTargetFriendly(%targetObject.getTarget(), %attackerTeam))
      {
         %curDamage = %targetObject.getDamageLevel();
         %availableDamage = %targetObject.getDataBlock().disabledLevel - %curDamage - 0.05;
         if (%amount > %availableDamage)
            %amount = %availableDamage;
      }
    }

   // if there's still damage to apply
   if (%amount > 0)
      %targetObject.applyDamage(%amount);
}

Force Field Door Bug

7/25/2008 1:52:07 PM

Got ya, I bet itis happening is because of being able to repack the FF's. Since you can deploy and undeploy as soon as the item is off your back that would make sense. There are actually two parts to the code that control the FF's. Hhmm, guess I need to delay the redeploying of FF's to correct this bug. Thanks for the info, I will take a look to see how long it will take to fix.,it is very hard to explain the steps because i time it by the sound the doors make when u deploy them. when u deploy them u hear the sound right? but the door doesn't appear for about 2 or 3 seconds. just before the sound finshes u redeploy it. the door is made after the sound but because u redeploied the beacon at the same time the door was made, the door remained there forever without the beacon there. therefore making the door last forever. If you're still confused then the only way better to explain it to u is to go into the game and show you myself.,Can you be more specific as to what steps you are taking. The code is setup so that the FF shape can't be created until the sensor object is there first. To track down the bug, having all of the steps you perform, or timing would be very helpful. Thanks for letting me know so I can track it down. ,if you time it just right u can deploy a ff door that doesn't have the little beacon thing so it becomes invincable and u can have infinite of these doors. its just a blue wall without the beacon. Basically unless you want to take alot of time all u have to do is make the ff doors unable to be redeploied so that once its there it stuck that way.,

ff doors

7/25/2008 1:52:07 PM

I changed it to make it more like the T1 version. I have gone back and forth on the idea and if more persons prefer it where they do not take damange I will change it back. ,Well, in that case away goes the FF door direct damage. I have needed to do a maint release anyway. I will work up the release and get it ready to go out with this and some minor changes.,I liked it better when you could not kill the FFDoor by hitting it anywhere .. turrets kill mine all the time .. _____________________________________________________________________ EG 1:___When i am flagD and im guarding the flag and set up turrets/defencez the flame turrets really suck when thay see a enemy behind the FFD its like half a sec and the force is gone and i getta "GREEN BOOMEY" placed in my lap **CATCH** "say goodbye to all my Defence Work" ____**WaVeZ**____ ______________________________________________________________________ EG 2:___All someone needs to do it set up a Flame/Rocket/Mortor turret near your FFD and when you run by "Its Gone!" _ "Do Not Pass Go" _ "Do Not Collect 200 Dollars" (((And Yet Again "GREEN BOOMEY" Placed Directly Up Your ShAzBoT!)) ====================================================================== ||-VOTE#2________KillEcLiPz_________Would like it the old way plz??-|| ======================================================================,in the new 2.5 mod release of anarchy u made the ff doors so u can attack any where to destroy it, but i liked it better before. did alot of people not like the old way or did you just change it for no reason?,

Shocklance turret

7/25/2008 1:52:07 PM

basicly as it says a shocklance turret. close range and is only placiable on buildings. besides the instant kill you get if you get too close to it, it should be cloaked forever unless it shoots. so its a good turret to have when they're alot of walls to come around the corner with.,

Models and designs

7/25/2008 1:52:07 PM

Grappling Hook - Difficulty Moderate

7/25/2008 1:52:07 PM

Xenolith

Here's my targeting laser from UltraXL, converted to a grapple-like thingy. I even will leave the commented out code from debugging and when I was experimenting with acceleration and gravity, making it more, "realistic". Even though it was more realistic, it wasn't any fun, so it was ditched.

If you use this code without giving me credit, I won't sue you, I'll just beat the crap out of you.

Code:
--------------------------------------------------------------------------------

function TargetingLaserImage::onFire(%data,%obj,%slot)
{
//   %p = Parent::onFire(%data, %obj, %slot);
//   %p.setTarget(%obj.team);
if (%obj.holdingFlag) return;
%energy = %obj.getEnergyLevel();
//   echo("%energy = " @ %energy);
   %muzzlePos = %obj.getMuzzlePoint(%slot);
   %muzzleVec = %obj.getMuzzleVector(%slot);
//echo("projectile distance " @ %data.projectile.maxRifleRange);
     %beamtime = 400;

%endPos = VectorAdd(%muzzlePos, VectorScale(%muzzleVec, %data.projectile.maxRifleRange));
// echo("%obj.client.heatSignature = " @ %obj.client.heatSignature);

   // did I miss anything? players, vehicles, stations, gens, sensors, turrets
   %hit = ContainerRayCast(%muzzlePos, %endPos, %SearchMask, %obj);
   %noDisplay = true;

   if (%hit !$= "0")
   {
%clientID = %obj.client;
if (%obj.client.beamer == 0 && %energy > 15)
  {
   %obj.client.beamer = 1;
        messageClient(%obj.getOwnerClient(), 'MsgBeamerStatus', '~wfx/weapons/cg_hard3.wav');
   %obj.setEnergyLevel(%energy - 15);
        beamerOn(%data, %obj, %hit, %slot);
  }
else
{
  %obj.client.beamer = 0;
      if(isObject(%obj.beamproj)) %obj.beamproj.schedule(%beamtime, "delete");
//  if (isObject(%obj.lastProjectile))
//     {
//   %obj.lastProjectile.delete();
//   %obj.lastProjectile = "";
//  }
  messageClient(%obj.getOwnerClient(), 'MsgBeamerStatus', '~wfx/weapons/ELF_underwater.wav');
}
//   echo("hitpos = " @ %hitpos);
//   echo("obj.position = " @ %obj.position);
}
}

function beamerOn(%data, %obj, %hit, %slot)
{
%beamtime = 400;
if(isObject(%obj.beamproj)) %obj.beamproj.schedule(%beamtime, "delete");

//  if (isObject(%obj.lastProjectile))
//     {
//   %obj.lastProjectile.delete();
//   %obj.lastProjectile = "";
//  }
// %clientID = %obj.client;
if (%obj.client.beamer != 1)
  return;
   %obj.setHeat(1.0); //max out the heat signature

     %hitobj = getWord(%hit, 0);
     %hitpos = getWord(%hit, 1) @ " " @ getWord(%hit, 2) @ " " @ getWord(%hit, 3);
        %xhit = getword(%hitpos, 0);
        %yhit = getword(%hitpos, 1);
        %zhit = getword(%hitpos, 2);
        %xobj = getword(%obj.position, 0);
        %yobj = getword(%obj.position, 1);
        %zobj = getword(%obj.position, 2);
        %x = %xhit - %xobj;
        %y = %yhit - %yobj;
        %z = %zhit - %zobj;
        %displacement = %x @ " " @ %y @ " " @ %z;
//    %hitpos = %x @ " " @ %y @ " " @ %z;
//    echo("displacement1 = " @ %displacement);
        %x = getword(%displacement, 0);
        %y = getword(%displacement, 1);
        %z = getword(%displacement, 2);
    %distance = mSqrt(%x * %x + %y * %y + %z * %z);
    %x = %x / %distance;
    %y = %y / %distance;
    %z = %z / %distance;
    %displacement = %x @ " " @ %y @ " " @ %z;
    if (%distance < 5 || %obj.client.beamer == 0)
    {
  %obj.client.beamer = 0;
  messageClient(%obj.getOwnerClient(), 'MsgBeamerStatus', '~wfx/weapons/ELF_underwater.wav');
     if(isObject(%obj.beamproj)) %obj.beamproj.schedule(%beamtime, "delete");
//  if (isObject(%obj.lastProjectile))
//     {
//   %obj.lastProjectile.delete();
//   %obj.lastProjectile = "";
//  }
  %velocity = VectorScale(%displacement, 5);
        %obj.setVelocity(%velocity);
  return;
}
//          %velocity = %obj.getVelocity();
//    %acceleration = VectorScale(%displacement, 20); // this defines the magnitude of the acceleration
//    echo("%acceleration = " @ %acceleration);
//    %velocity = VectorAdd(%velocity, %acceleration);
%z = %z + 0.25;
    %fix = %x @ " " @ %y @ " " @ %z;

    if (%distance < 55) %velocity = VectorScale(%fix, (%distance * 2));
else     %velocity = VectorScale(%fix, 110); //was 500
          %obj.setVelocity(%velocity);

// echo("velocity = " @ %velocity);

// %velocity = VectorScale(%obj.getVelocity(), 4);

//        %x = getword(%velocity, 0);
//        %y = getword(%velocity, 1);
//        %z = getword(%velocity, 2);

//        if(mSqrt(%x * %x + %y * %y + %z * %z) > 300)
//                %velocity = VectorScale(VectorNormalize(%velocity), 300);
   %muzzlePos = %obj.getMuzzlePoint(%slot);

//Below is some code I should try
//%VectorBetween = VectorSub(%Position1, %Position2);
//%Length = VectorLen(%VectorBetween);
//%data.Projectile.maxRifleRange = %Length;
// %Projectile = new TargetProjectile()

   %obj.beamproj = new (%data.projectileType)() {
       dataBlock        = %data.projectile;
       initialDirection = %displacement;
       initialPosition = %muzzlePos;
//      sourceObject     = %obj;
       damageFactor     = 0;
       sourceSlot       = 0; //%slot
       fadeTime   = %beamtime;
    };
//   %obj.lastProjectile = %p;
   MissionCleanup.add(%obj.beamproj);
//      %this.ELFrecur = %this.schedule(32, checkELFStatus, %data, %target, %targeter);

schedule(%beamtime,0,"beamerOn",%data,%obj,%hit,%slot);
}

Jet Particles

7/25/2008 1:52:07 PM

----------------------------------------------------------------------------------------

                 Jet Particle Tut- by: MircoMitch

                Brought Back to you- by: Drumstix42

________________________________________________________________________________________

Step 1:
Figuring out what color you want your jet particle to be!

Well, this is really easy, for Windows users do this: Start => Run => mspaint

Thats right good, old, Microsoft Paint comes into play.(Wow, paint actually has a
purpose now) MAC Uses- Your screwed since I don't know MACs =) Ok once in paint,
click on Colors => Edit Colors

Once the window appears click Define Custom Colors.
Now this is the easy part, just got to click, and move the slider bar to a color
you like. Once you find the perfect one thats good =)
Ok now here is how Tribes 2 reads the colors. colors[0] = "R G B A";

Incase you didn't know it reads the colors like so
Red Green Blue Alpha - Alpha is just the transparency I believe.

Now you see in mspaint under the slider bar, you see:
Red : #
Green: #
Blue: #

Good idea to write these numbers down. Just the rounded digits, you will see in a moment.

Open up calculator in Windows. Start => Run => calc
Ok now lets do the Red. I am using the number 19 for example.

Type into the calculator 19/255 19 divided by 255.
And your answer will be 0.074509803921568627450980392156863 a long ass
string of numbers, but in our case we will round to the hundreths.
So your number will just 0.07 for Red.

Now for the green.
45/255 outcome is 0.17647058823529411764705882352941. So we will use 0.18 for green.

Now for the blue.
221/255 outcome is 0.86666666666666666666666666666667 So we will just use 0.9.

Alpha we don't worry about yet. So here is what we got

Red-0.07
Green-0.18
Blue-0.9

So in Tribes 2 it would be like this colors[0]="0.07 0.18 0.9 A"; //A represents Alpha.

This means we got a real nice blue color! Fun stuff.

Step 2:
Making the particle effect itself.
Ok open your player.cs once you got your color selection and numbers known.

Ok, what we are going to do is make this color you selected effective to the scout armor!
Ok, find these datablocks: (Right next to each other)

datablock ParticleData(HumanArmorJetParticle)

datablock ParticleEmitterData(HumanArmorJetEmitter)

Make an exact copy of them and paste them right below and modify them to read this,
note in the "datablock ParticleEmitterData" change the particles to the
ScoutArmorJetParticle.

datablock ParticleData(ScoutArmorJetParticle)

datablock ParticleEmitterData(ScoutArmorJetEmitter)

If you couldn't do that I did it for you.

datablock ParticleData(ScoutArmorJetParticle)
{
   dragCoefficient      = 0.0;
   gravityCoefficient   = 0;
   inheritedVelFactor   = 0.2;
   constantAcceleration = 0.0;
   lifetimeMS           = 100;
   lifetimeVarianceMS   = 0;
   textureName          = "particleTest";
   colors[0]     = "0.32 0.47 0.47 1.0";
   colors[1]     = "0.32 0.47 0.47 0";
   sizes[0]      = 0.40;
   sizes[1]      = 0.15;
};

datablock ParticleEmitterData(ScoutArmorJetEmitter)
{
   ejectionPeriodMS = 3;
   periodVarianceMS = 0;
   ejectionVelocity = 3;
   velocityVariance = 2.9;
   ejectionOffset   = 0.0;
   thetaMin         = 0;
   thetaMax         = 5;
   phiReferenceVel = 0;
   phiVariance      = 360;
   overrideAdvances = false;
   particles = "ScoutArmorJetParticle";
};

Ok, look at the datablock ParticleData(ScoutArmorJetParticle) and you will see
the colors[0] and colors[1], this is where the majic begins for you.
Now remeber how Alpha was A, you will see why now. I don't recommend changing
them for the armors at all since they will look nice, but feel free to do it.

So remeber all them digits we got? This is where we input them.

So the outcome should look like this, remeber your color, will not look like
this if you chose another color.

colors[0] = "0.07 0.18 0.9 1.0";
colors[1] = "0.07 0.18 0.9 0";

Ok now time to make the particle trail behind you. In the ScoutArmorJetParticle
datablock, you will see lifetimeMS = 100; Make it read:

lifetimeMS = 1000;

You can change it to what you prefer.

Step 3:
Still in player.cs find this datablock for the scout:

datablock PlayerData(LightMaleHumanArmor) : LightPlayerDamageProfile

And inside that datablock you will find:
jetEmitter = HumanArmorJetEmitter;

Change it to:
jetEmitter = ScoutArmorJetEmitter;

Congratulations you just added a Trailing Jet Particle with a color =)

Adding Armors

7/25/2008 1:52:07 PM

_______________________________________________________________________
- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
- - - - - - - - - - Adding Armors:by Drumstix42 - - - - - - - - - - -
- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
- --- --- --- --- --- --- --- --- -
_______________________________________________________________________

STEP #1:

-----
--------------
Player.cs
--------------
-----
1a)
You'll first need to make your Armor's properites such as when you define
a weapon's attributes. You'll need to copy one of the 3 player Datablocks,
either the light, medium, or heavy. Their datablocks are pretty long. Do
a search for either:

LightPlayerDamageProfile
   MediumPlayerDamageProfile
             or
   HeavyPlayerDamageProfile

It's best to find out its starting line# and last line# of its
datablock first. Now go ahead and copy one of these datablocks. It's usually
easiest to keep the same sized armors around each other. So if you copied
the 'LightPlayerDamageProfile' Datablock, just paste it right under it.
It's also best to keep spaces between what you pasted and what was already
there. This keeps things easier to find.

There are one or two things you can change, one of them being manditory.
For now, I'll just assume you copied the Light armor. This first line
is what you'll need to change:

datablock PlayerData(LightMaleHumanArmor) : LightPlayerDamageProfile

The part you have to change is the:

(LightMaleHumanArmor)

All you have to do is give a new name, replacing Light with anything you'd
like to name your armor.
The second thing you can change is if you'd like your new armor to have its
own damage profile. This meaning you'd be able to have your new armor have
different damage properites compared to the Light armor:

: LightPlayerDamageProfile

As before, you would replace Light with your armor's name.
If you would your new armor to have the same damage properties at the light,
you would then leave it as is. There are many variables that you can change
in your new armor such as speed, energy use, heat multipler, and it's load
out which is most important. Your new armor's load out capabilitescan be
found under and some above:

// Inventory restrictions

Above thats part are 3 lines:

   maxWeapons = 3;           // Max number of different weapons the player can have
   maxGrenades = 1;          // Max number of different grenades the player can have
   maxMines = 1;             // Max number of different mines the player can have

Each line is pretty self explanitory. This shows this armor can hold 3 different
weapons, 1 type of grenade, and 1 type of mine.
Under the '//Inventory restrictions' are the lines that tell if an armor can have a
weapon and how much ammo and if it can carry a pack or deployable. For weapons/
packs/deployables, 1 means it can carry it, and 0 means it can't. Then for ammo,
the number represents the ammo amount. Like said, pretty simple.

1b)
Next, we have to make sure your new armor can be used as a BioDerm and as a
Female. If we don't, BAD things will happen. So, we now scroll down passed all
the armor datablocks and we reach the smaller datablocks of BioDerm and Females.

Still assuming we're doing a light class armor we would copy the Female Datablock:

//----------------------------------------------------------------------------
datablock PlayerData(LightFemaleHumanArmor) : LightMaleHumanArmor
{
   shapeFile = "light_female.dts";
   waterBreathSound = WaterBreathFemaleSound;
   jetEffect = HumanMediumArmorJetEffect;
};

And paste it right under as before. You then change where it says Light twice on
the first line, to the name of your armor.
Next, we scroll down past the females and reach the BioDerms. Before each BioDerm
datablock, there are BioDerm foot prints datablocks which we should just ignore.
Copy the LightBioDerm datablock:

datablock PlayerData(LightMaleBiodermArmor) : LightMaleHumanArmor
{
   shapeFile = "bioderm_light.dts";
   jetEmitter = BiodermArmorJetEmitter;
   jetEffect = BiodermArmorJetEffect;

debrisShapeName = "bio_player_debris.dts";

   //Foot Prints
   decalData   = LightBiodermFootprint;
   decalOffset = 0.3;

waterBreathSound = WaterBreathBiodermSound;
};

And paste it right under. Once again, changing the Light twice in the first line
to your armors name.

Now done the hardest part of adding an armor to your mod, you may now save
player.cs and exit!

STEP #2:

-----
--------------
damageTypes.cs
--------------
-----
~**!Most Importantly: This Step is ONLY needed, if you decided you want yournew
armor to have it's own damage profile!**~

Scroll all the way to the bottom of the file where the Armor damage profiles are
kept:

// PLAYER DAMAGE PROFILES

I would then copy the LightPlayerDamageProfile and paste it right under as usual:

datablock SimDataBlock(LightPlayerDamageProfile)
{
   damageScale[$DamageType::Blaster] =   1.3;
   damageScale[$DamageType::Bullet] =   1.2;
   damageScale[$DamageType::ELF] =   0.75;
   damageScale[$DamageType::ShockLance] =  1.0;

.....all the way down to.....

   damageScale[$DamageType::Ground] =   1.0;
   damageScale[$DamageType::Explosion] =  1.0;
   damageScale[$DamageType::Lightning] =  1.0;
};

And if your catching on, you would change the Light in '(LightPlayerDamageProfile)'
to your armors name, just as we did in player.cs if you changed it to have its
own damage profile. For now, just leave all the numbers the same, for you can come
back later when you want to ajust it's damage properties.

Now, save your file and exit. On to the next step!

STEP #3:

-----
--------------
inventoryHud.cs
--------------
-----
In this step we will put in very simple code to make your new armor show up on the
inventory hud in-game. This step is very simple.

First scroll down a little to about line# 20. Here you see a simple list of existing
armors:

$InvArmor[0] = "Scout";
$InvArmor[1] = "Assault";
$InvArmor[2] = "Juggernaut";

And right under that we see another list:

$NameToInv["Scout"] = "Light";
$NameToInv["Assault"] = "Medium";
$NameToInv["Juggernaut"] = "Heavy";

The first list we see tells the game what text to show in the hud. The second list
takes the text and tells the game what the armor really is. Ass you can see each
list does this. It prints Scout in the list, and works of the 'Light' datablock.
Now to add your armor is quite simple. It's usually good to keep the armor sizes in
order. So lets make our lists look like this:

$InvArmor[0] = "Scout";
$InvArmor[1] = "ARMOR's TEXT TO APPEAR GOES HERE";
$InvArmor[2] = "Assault";
$InvArmor[3] = "Juggernaut";

$NameToInv["Scout"] = "Light";
$NameToInv["ARMOR's TEXT TO APPEAR GOES HERE"] = "NAME OF ARMORS DATABLOCK";
$NameToInv["Assault"] = "Medium";
$NameToInv["Juggernaut"] = "Heavy";

-------------------
For example, if your armor's datablock name was Sniper, and you wanted it to show L. Sniper on
the hud, you'd do this:

$InvArmor[1] = "L. Sniper";

and

$NameToInv["L. Sniper"] = "Sniper";
-------------------

And that's all for inventoryHud.cs. Exit and Save!

STEP #3:

-----
--------------
Player.cs
--------------
-----
I'm not to sure what this does besides tell the game how long your armors name is.
Anyway, do a search for this:

function Player::getArmorSize(%this)

The part we're looking at is this:

   if (getSubStr(%dataBlock, 0, 5) $= "Light")
      return "Light";
   else if (getSubStr(%dataBlock, 0, 6) $= "Medium")
      return "Medium";
   else if (getSubStr(%dataBlock, 0, 5) $= "Heavy")
      return "Heavy";
   else
      return "Unknown";

All we need to do is add in your armor and make the second number 0, ?) equal how
many letters your armor is. For an example, lets say your armors name is Dominion,
your code would then look like this:

else if (getSubStr(%dataBlock, 0, 8) $= "Dominion")
return "Dominion";

And all together, like this:

And that's it! You've now hopefully adding a new armor to your mod.
Congratulations! And good luck.